docker-radarr/flake.nix

{
  description = "Radarr";

  inputs = {
    nixpkgs = {
      url = "nixpkgs/nixos-22.11";
    };
  };

  outputs = { self, nixpkgs }@inputs:
    let
      system = "x86_64-linux";
      branch = "master";
      version = "4.3.2.6857";
      os = "linux";
      arch = "x64";
      pkgs = import nixpkgs {
        inherit system;
        overlays = [
          (
            self: super:
              {
                radarr =
                  super.radarr.overrideAttrs (old: {
                    inherit version;
                    src = builtins.fetchurl {
                      url = "https://github.com/Radarr/Radarr/releases/download/v${version}/Radarr.${branch}.${version}.${os}-core-${arch}.tar.gz";
                      sha256 = "sha256:0bxmyifn8q7sgf7y98lf2c4fva49c6m79is3h7l1a869y0g6irpc";
                    };
                  });
              }
          )
        ];
      };
    in
    {
      packages.${system}.default = pkgs.dockerTools.buildLayeredImage
        {
          name = "radarr";
          tag = "latest";
          maxLayers = 2;
          contents = [
            pkgs.cacert
            pkgs.coreutils-full
            pkgs.bash
            pkgs.util-linux
          ];
          fakeRootCommands = ''
            mkdir /config
            mkdir /media
            chown 5000:5000 /config
            chown 5000:5000 /media
          '';
          config = {
            Cmd = [
              "${pkgs.radarr}/bin/Radarr"
              "-nobrowser"
              "-data=/config"
            ];
            WorkingDir = "${pkgs.radarr}/share/radarr-${version}/UI";
            User = "5000:5000";
            Env = [
              "COMPlus_EnableDiagnostics=0"
              "XDG_CONFIG_HOME=/config/xdg"
            ];
            ExposedPorts = {
              "7878/tcp" = { };
            };
            Volumes = {
              "/config" = { };
              "/media" = { };
            };
          };
        };
    };
}